Энкодер и Arduino: схема подключения KY-040, скетч и борьба с дребезгом

const int PIN_CLK = 2;
const int PIN_DT  = 3;
const int PIN_SW  = 4;

volatile int counter = 0;
volatile unsigned long lastTurn = 0;

void onTurn() {
  // отсекаем дребезг: щелчки чаще 3 мс — это стук контактов, а не рука
  unsigned long now = millis();
  if (now - lastTurn < 3) return;
  lastTurn = now;

  // если второй сигнал отличается от первого — крутят вправо
  if (digitalRead(PIN_DT) != digitalRead(PIN_CLK)) {
    counter++;
  } else {
    counter--;
  }
}

void setup() {
  Serial.begin(9600);
  pinMode(PIN_CLK, INPUT);
  pinMode(PIN_DT, INPUT);
  pinMode(PIN_SW, INPUT_PULLUP);   // кнопка замыкает на землю

  attachInterrupt(digitalPinToInterrupt(PIN_CLK), onTurn, FALLING);
}

void loop() {
  static int shown = 0;
  if (counter != shown) {
    shown = counter;
    Serial.println(shown);
  }

  if (digitalRead(PIN_SW) == LOW) {
    Serial.println("Нажата ручка");
    counter = 0;
    delay(300);                    // чтобы одно нажатие не считалось десятью
  }
}